Datums

Home > Datums berekenen

> Algemene info over functies
> Mijn boeken
> Training Excel op uw bedrijf

Smaakt dit naar meer?
* Ik kom graag op uw bedrijf een training Excel verzorgen.
* Vertel uw collega's en vrienden over deze website.

* Ik verzamel speciale USB-sticks.
U mag er een opsturen naar
Mussenveld 129
7827 AJ Emmen
Ik laat me graag verrassen.

Vlot leren rekenen met datums

Ik kom graag een training Excel op uw bedrijf geven. Ook over talloze andere interessante rekenfuncties. In overleg spreken we af wat u gaat leren. Dit kan met beginners en gevorderden, en kan gaan over Excel 2003, 2007, 2010, 2013 of 2016.

Meer over de training Excel

Uitgebreid lezen over rekenen met datums?

Alle functies op deze pagina, plus de functies:
* WERKDAG
* WERKDAG.INTL
* NETTO.WERKDAGEN en
* NETWERKDAGEN.INTL
leg ik uitgebreid uit in hoofdstuk 6 van mijn boek Excel voor Professionals, Derde Editie.

Ze worden met afbeeldingen verhelderd.
Klik op het boek om het in te kijken en te bestellen.
Daarin leest u bijvoorbeeld ook hoe u een projectplanning als een Gantt-grafiek weergeeft.

Uw projecten plannen met Excel

Met dit schema kunt u uw projecten plannen.
* vul in hoeveel werkdagen het project duurt
* geef de Startdatum op

Moet het volgende project aansluiten?
* kies dan het aantal dagen
* kies voor of na
* het begin of eind van het vorige project.

blauw zijn de dagen volgens de planning,
oranje zijn vrije dagen (die worden niet meegeteld),
rood is de deadline, de laatste dag.

* Alleen de werkdagen worden gepland: weekends, feest- en vrije dagen worden automatisch overgeslagen.
* Bij o.a. Carnaval en Goede Vrijdag kunt u kiezen of dat werkbare dagen zijn.
* U kunt zelf niet-werkbare dagen en vakanties toevoegen.
Project Planning werkt in Excel 2007, 2010 en 2013.

U kunt een gratis probeerversie downloaden.

Bestel het Excel-schema Project Planning voor
slechts € 25,-.

Project Planning bestellen

Met dit schema in Excel spaart u de aanschaf van MS Project uit.

Koningsdag berekenen

Vanaf 2014 wordt koningsdag gevierd op 27 april. Maar als dat op zondag valt, gaat het naar zaterdag 26 april.
U berekent koningsdag in Excel met de formule
=ALS(WEEKDAG(DATUM(C2;4;27))=1;DATUM(C2;4;26);DATUM(C2;4;27))
Hier staat het jaartal in cel C2
De formule houdt in: als de weekdag van 27 april een 1 is (d.w.z.: op zondag valt), neem dan 26 april; geef in de andere gevallen 27 april.
Het kan ook met een kortere formule:
=DATUM(C2;4;27)-ALS(WEEKDAG(DATUM(C2;4;27))=1;1;0)
Deze houdt in: neem de datum 27 april en als de weekdag van 27 april een zondag is, trek er dan 1 van af.

Koningsdag of koninginnedag?

In de jaren vóór 2014 is koninginnedag op 30 april. Ook daarbij geldt de regel: valt dat op zondag, dan wordt het een dag eerder. Als het jaartal in C2 staat, is uw formule
=ALS(C2>2013;ALS(WEEKDAG(DATUM(C2;4;27))=1;DATUM(C2;4;26);DATUM(C2;4;27));ALS(WEEKDAG(DATUM(C2;4;30))=1;DATUM(C2;4;29);DATUM(C2;4;30)))
Die betekent: als het jaartal hoger is dan 2013, kijk dan of de weekdag van 27 april een 1 is (op zondag valt), en neem dan 26 april; geef anders 27 april; en als het jaartal niet hoger is dan 2013, kijk dan of de weekdag van 30 april een 1 is (op zondag valt), en neem dan 29 april; geef anders 30 april.
Deze kan ook compacter:
=ALS(WEEKDAG(DATUM(C2;4;ALS(C2>2013;27;30)))=1;DATUM(C2;4;ALS(C2>2013;26;29));DATUM(C2;4;ALS(C2>2013;27;30)))
Hier staat: als de weekdag van (na 2013 op 27 en anders op 30) april 1 is (op zondag valt), geef dan (na 2013 26 en anders 29) april; en geef anders de datum van (na 2013 op 27 en anders op 30) april.

Hoe Excel rekent met datums

Voor het rekenen met datums kent Excel aan één dag de waarde 1 toe. Het programma telt de dagen vanaf 1 januari 1900. Bijvoorbeeld 1 januari 2000 heeft het getal 36526, want het was toen 100 jaar en 25 schrikkeldagen later.
Dat u zo'n getal als een datum ziet, komt alleen door de opmaak. Deze opmaak als datum komt automatisch als u een datum invoert als 7-3-2012 of als 7/3/2012.
Tip 1: u voert de datum van vandaag in door te drukken op Ctrl+; (puntkomma) gevolgd door Enter.
Tip 2: valt de datum in het huidige jaar, dan hoeft u het jaartal er niet bij te typen, dat voegt Excel eraan toe.
Typ 7-3 en u krijgt 7-3-2012 (kijk hiervoor in de formulebalk).

Aantal dagen tussen twee datums

Wilt u het verschil tussen twee datums weten, dan trekt u ze van elkaar af. Typ bijvoorbeeld in A1 de ene datum en in B2 de andere datum (B2 moet later vallen dan A2).
Zet ernaast de formule
=B2-A2
U ziet het aantal dagen dat ertussen ligt.

Feestdagen in een willekeurig jaar

Geef een jaar op en Excel laat de feestdagen zien.
Download dit kant-en-klare werkblad met feestdagen.

Zelf leren werken met Excel?

Ik kom graag op uw bedrijf een training Excel geven. Over datums en over talloze andere interessante rekenfuncties. In overleg spreken we af wat u gaat leren. Dit kan met beginners en gevorderden, en kan gaan over elke versie van Excel.

Meer over de training Excel

Formules voor datums

Functie in een voorbeeld:
=DAG("1-7-2014")
=MAAND("1-7-2014")
=JAAR("1-7-2014")
=("1-7-2014"-"1-1-2014")
=DAGEN360("1-1-2014";"1-7-2014")

=DATUMVERSCHIL("1-1-2014";"1-7-2014";"d")
=DATUMVERSCHIL("1-1-2012";"1-7-2014";"m")
=DATUMVERSCHIL("1-1-2010";"1-7-2014";"y")
=DATUMVERSCHIL("1-1-2010";"1-2-2014";"yd")
=DATUMVERSCHIL("1-1-2010";"1-7-2014";"ym")
=DATUMVERSCHIL("1-1-2010";"14-7-2014";"md")

Toelichting:
Geef uit een datum de dag van de maand
Geef uit een datum de maand
Geef uit een datum het jaartal
Aantal dagen tussen twee datums
Aantal dagen tussen twee datums met een jaar van 360 dagen
Aantal dagen tussen de datums
Aantal hele maanden tussen de datums
Aantal hele jaren tussen de datums
Aantal dagen, zonder de jaren
Aantal maanden, zonder de jaren
Aantal dagen, zonder de jaren en maanden

Uitkomst:
1
7
2014
181
180

181
30
4
31
6
14

=DATUM(2014;3;7)
=DATUMWAARDE("7-3-2014")
=JAAR.DEEL("1-1-2014";"1-7-2014")

=LAATSTE.DAG("1-7-2014";3)

=NETTO.WERKDAGEN("1-1-2014";"31-12-2014")

=WEEKDAG("1-7-2014")

=WEEKNUMMER("1-7-2014")

=WERKDAG("1-7-2014";7)
=ZELFDE.DAG("1-7-2014";12)

=ZELFDE.DAG("1-7-2014";12,5*12)

Stel datum samen uit: jaar, maand, dag
Geef serieel getal van een datum
Geef het deel van een jaar tussen de datums, als een getal tussen 0 en 1
Tel x maanden verder en geef de laatste dag van die maand
Geef het aantal hele werkdagen tussen twee datums
Geef uit een datum de dag van de week:
van 1=zondag tot en met 7=zaterdag
Geef het weeknummer van een datum
* volgens Amerikaanse telling!
Zie voor Europese telling hieronder
Geef vanaf een datum x aantal werkdagen later
Geef een datum, een x aantal maanden na de opgegeven datum
Bijv. 12,5 jaar later geeft u op als 12,5 maal 12 maanden

07-03-2014
41.705
0,5

31-03-2014

261

3

27

10-7-2014
1-7-2015

1-1-2027

Formules met VANDAAG

In deze voorbeelden is het 'vandaag' 15 mei 2014
Functie in een voorbeeld:
=VANDAAG()
=ZELFDE.DAG(VANDAAG();1)
=LAATSTE.DAG(VANDAAG();0)
=LAATSTE.DAG(VANDAAG();1)
=GEHEEL((MAAND(VANDAAG())+2)/3)
=GEHEEL((MAAND(VANDAAG())+2)/3)+1

Toelichting:
Geef de datum van vandaag
Vandaag over een maand
Einde van de huidige maand
Einde van de volgende maand
Huidige kwartaal
Volgende kwartaal

Uitkomst:
15-05-2014
15-06-2014
31-05-2014
30-06-2014
2
4

Leeftijd berekenen

U kunt met Excel iemands leeftijd berekenen als u de geboortedatum weet. Dat kan op twee manieren.

Hoe oud wordt iemand ergens in dit jaar?
U trekt hiervoor het geboortejaar af van het huidige jaar.
Staat de geboortedatum in cel A2, dan neemt u
=JAAR(VANDAAG())-JAAR(A2)

Hierbij maakt het niet uit, wanneer in het jaar de verjaardag valt.

Hoe oud is iemand op een bepaalde dag?
U wilt de leeftijd weten op een bepaalde peildatum, bijvoorbeeld: hoe oud is iemand op 15-9-2014?
Typ dan de datum 15-9-2014 eenmalig in bijvoorbeeld cel C1. Staat de eerste datum in A2, dan is uw formule
=GEHEEL((C$1-A2)/365,25)

Zie voor de toelichting hiernaast.
Deze kunt u omlaag kopiëren. Omdat er een $ in C$1 staat, zullen alle kopieën verwijzen naar de cel met deze datum.
Wilt u de leeftijd weten op een andere peildatum, dan hoeft u alleen de datum in cel C1 maar te veranderen.

Als alternatief kunt u gebruiken:
=DATUMVERSCHIL(A2;C$1;"y")

Hoe oud is iemand vandaag?
Het ligt voor de hand om de formule te nemen (als de geboortedatum in cel A2 staat):
=(VANDAAG()-A2)/365,25
Het verschil tussen vandaag en A2 in dagen, gedeeld door 365,25 (het gemiddelde aantal dagen per jaar inclusief 1 schrikkeldag eens per vier jaar).
Maar de uitkomst is een getal met decimalen, die worden afgerond op het dichtstbij zijnde hele getal (maakt u de decimalen maar eens zichtbaar met Meer decimalen). Dat geeft niet altijd een betrouwbare uitkomst, want u moet alleen het hele getal uit de uitkomst hebben.
Dat krijgt u met de formule
=GEHEEL((VANDAAG()-A2)/365,25)

Ook hier staat de datum in cel A2. Het verschil wordt gedeeld door 365,25 en naar beneden afgerond.

Alternatief: u krijgt de leeftijd op dit moment ook met
=DATUMVERSCHIL(A2;VANDAAG();"y")

Als u dit op een lange reeks datums toepast, is het verstandig om eenmaal =VANDAAG() in een cel te plaatsen en alle andere formules daarnaar te laten verwijzen. Want VANDAAG() in een lange serie moet in alle formules apart worden opgehaald en dat vertraagt het werkblad.

Op welke datum valt deze verjaardag?

Welke dag van de week is die datum?

Iemand is geboren op 17-5-78 en u wilt weten op welke dag van de week de verjaardag dit jaar valt.
Typ, bijvoorbeeld in cel B2, de datum 17-5-1978.
Om 17-5 van dit jaar te krijgen, hebt u de volgende onderdelen nodig:
* JAAR(VANDAAG()) geeft het jaartal van vandaag;
dit mag ook met JAAR(NU())
* MAAND(B2) geeft de maand van B2
* DAG(B2) geeft de dag van B2.

Met deze onderdelen geeft de functie DATUM de datum uit B2 in het huidige jaar; de formule is
=DATUM(JAAR(VANDAAG());MAAND(B2);DAG(B2))

Wilt u van een datum zien op welke dag van de week die valt, dan regelt u dat met de Opmaak.
Klik op de cel met de datum.
In Excel 2003:
Klik op Opmaak, Celeigenschappen. Klik op Aangepast (onder in het venster) en typ in het vak onder Type de code dddd d mmmm jjjj

In Excel 2007, 2010 en 2013:
Open in het tabblad Start het opmaakmenu boven in de groep Getal. Klik in dat menu op Lange datumnotatie.
De datum 16-7-1985 ziet er dan uit als:
dinsdag 16 juli 1985

Of gebruik de functie WEEKDAG. Met
=WEEKDAG(B2)
ziet u een cijfer 1 t/m 7, voor zondag t/m zaterdag.

Jubileum voorspellen

Typt u een datum in bijvoorbeeld cel A2, dan vindt u de datum 25 jaar later met de volgende formule:
=DATUM(JAAR(A2)+25;MAAND(A2);DAG(A2))
In Excel 2007, 2010 en 2013 kan dit ook met
=ZELFDE.DAG(A2;25*12)

Wilt u weten wanneer het 12,5 jaar na de datum in A2 is, dan neemt u
=DATUM(JAAR(A2);MAAND(A2)+12,5*12;DAG(A2))
In Excel 2007, 2010 en 2013 kan dit ook met
=ZELFDE.DAG(A2;12,5*12)

Wanneer zijn wij samen 100 jaar?

Ook een mooie mijlpaal. Dat berekent u als volgt.
Typ de geboortedatum van de een in cel D2, en die van de ander in E2.
Typ in G3 de formule
=GEMIDDELDE(D2:E2)
U krijgt dan het gemiddelde van de beide geboortedata.
Typ in cel D5 het getal 100 (als u wilt weten wanneer u samen 100 jaar wordt).
Typ in cel E5 de formule
=G3+D5/2*365,25
Maak de cellen met datums op als Datum en u ziet wanneer u de mijlpaal bereikt.

Het kan ook korter
U kunt de stap van de formule in cel G3 ook overslaan.
Typ wel de geboortedatums in cel D2 en in E2.
En typ in cel D5 het getal 100 (als u wilt weten wanneer u samen 100 jaar wordt).
Typ in cel E5 de formule
=GEMIDDELDE(D2:E2)+D5/2*365,25

Als u wilt weten wanneer u samen 50 wordt, hoeft u alleen het getal in cel D5 aan te passen.

De formules hieronder kunt u ook in een gratis bestand downloaden.

Datum van Pasen berekenen

De christelijke feesten in het voorjaar hangen samen met de datum van Pasen. Pasen valt op de eerste zondag na de eerste volle maan na het begin van de lente (21 maart).
Tot het jaar 2078 klopt deze formule:

Deze formule klopt tot 2368:

Typ een jaartal in cel C3 (tussen 1900 en 9999).
Met de volgende formule berekent Excel de datum van Eerste Paasdag voor elk willekeurig jaar.
Het jaartal staat in C3.

=VAST(("4/"&C3)/7+REST(REST(C3;19)*19-7;30)*14%;0)*7-6

=AFRONDEN.BENEDEN(DATUM(C3;5;DAG(MINUUT(C3/38)/2+56));7)-34
Plaats deze formule in cel C8.
De volgende feesten worden afgeleid van de Paasdatum en verwijzen daarom steeds naar C8.

Feestdagen berekenen

Carnaval
Aswoensdag
Goede Vrijdag
Tweede Paasdag
Hemelvaartsdag
Eerste Pinksterdag
Tweede Pinksterdag

Kerst berekent u met de functie DATUM
Eerste Kerstdag
Tweede Kerstdag

=C8-49
=C8-46
=C8-2
=C8+1
=C8+39
=C8+49
=C8+50

=DATUM(C3;12;25)
=DATUM(C3;12;26)

in cel C5
in cel C6
in cel C7
in cel C9
in cel C10
in cel C11
in cel C12

in cel C13
in cel C14

Andere bijzondere datums
Begin van zomertijd - laatste zondag in maart
Begin van wintertijd - laatste zondag in oktober
Moederdag - tweede zondag in mei
Vaderdag - derde zondag in juni
Prinsjesdag - derde dinsdag in september

Het Chinees Nieuwjaar berekent u met

Het jaartal staat in cel C3.
=DATUM(C3;3;31)-WEEKDAG(DATUM(C3;3;31))+1
=DATUM(C3;10;31)-WEEKDAG(DATUM(C3;10;31))+1
=DATUM(C3;5;14)-WEEKDAG(DATUM(C3;5;14))+1
=DATUM(C3;6;21)-WEEKDAG(DATUM(C3;6;21))+1
=DATUM(C3;9;19)-WEEKDAG(DATUM(C3;9;19))+3

=GEHEEL(DATUM(C3-1;12;21)+61,6-REST(DATUM(C3-1;12;21);(19*354+11*355)/360))+ALS(EN(REST(REST(C3;29,53);19)>8,6;REST(REST(C3;29,53);19)<10,6);1;0)

Islamitische feesten:

Begin van de Ramadan

Suikerfeest - 30 dagen later
Offerfeest - 14 weken / 98 dagen later

Joodse feesten:

Rosj haSjana - Nieuwjaar

MAAR: Rosj haSjana valt nooit op een woensdag, vrijdag of zondag, dus moet de volgende aanvulling erbij:

Yom Kippoer - Grote verzoendag
Soekot - Loofhuttenfeest
Simchat Thora - Vreugde der Wet

Typ een jaartal in cel C3 (tussen 1900 en 9999) en zet in cel C25:
=GEHEEL((C3-1900)*19*354+11*355)/360*12+1421,44)

=C25+30  (in cel C26)
=C25+98  (in cel C27)

Het jaartal staat in C3
de volgende formule komt in cel B30:
=DATUM(C3;8;31)+6,05+1,554*REST(12*(REST(C3;19)+1);19)+0,25*REST(C3-1900;4)-0,003*(C3-1900)

Deze moet erbij in cel C30:
=B30+ALS(OF(WEEKDAG(B30)=1;WEEKDAG(B30)=4;WEEKDAG(B30)=6;EN(WEEKDAG(B30)=2;REST(12*(REST(C32;19)+1);19)>11));1;ALS(EN(WEEKDAG(P71)=3;REST(12*(REST(A2;19)+1);19)<12);2;0))

=C30+9  (in cel C31)
=C30+14  (in cel C32
=C30+22  (in cel C33)

Formule voor Europees weeknummer

Als u het weeknummer van een datum berekent met de functie WEEKNUMMER, klopt de uitkomst niet altijd. Dat komt doordat Excel voor deze functie het Amerikaanse systeem gebruikt. In de VS is de week met 1 januari altijd week 1 en begint week 2 op de zondag erna. Daardoor heeft week 1 meestal geen zeven dagen. Bijvoorbeeld in week 1 van 2010 zitten alleen 1 en 2 januari.

Maar de Europese telling werkt volgens ISO. In Europa geldt een weeknummer altijd voor zeven dagen. De week met de eerste donderdag van het jaar is week 1.
Daardoor krijgt u in sommige jaren een verschil.

U krijgt het weeknummer volgens de Europese telling met de formule:
=(A1-WEEKDAG(A1-1)+4-(GEHEEL(DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;2)/7)*7-2))/7
In dit voorbeeld staat de datum in cel A1.

Functie voor Europees weeknummer in Excel 2013

In Excel 2013 is de functie ISO.WEEKNUMMER geïntroduceerd en is dit gedoe voorbij.
Als de datum in A1 staat, is uw formule
=ISO.WEEKNUMMER(A1)
U krijgt het weeknummer van deze datum volgens het ISO-systeem.
Deze functie is nieuw vanaf Excel 2013 en werkt dus niet in oudere versies.

Help! Ik zie geen datum, maar een groot getal

Zoals bovenaan uitgelegd, verwerkt Excel een datum als een getal. Alleen door de opmaak ziet u dat als een datum.
* Ziet u onverwacht een groot getal rond de 40.000 en wilt u daar een datum zien, maak die cel dan op als Datum.
* Misschien hebt u per ongeluk op de toetsen Ctrl+T gedrukt. Daardoor ziet u namelijk alle formules in het werkblad in plaats van hun uitkomsten. En datums veranderen dan in hun getalswaarde. Druk nogmaals op Ctrl+T en u ziet de getallen weer als datums.

Dit houdt dus ook in: wilt u weten welke getalswaarde achter een datum in uw werkblad zit, klik dan in de tab Start op de keuzelijst Getalnotatie (in de groep Getal); er gaat een keuzelijst open. Kijk daarin bij Getal en u ziet de achterliggende getalswaarde van die datum.

Werkplanning: lijst met werkdagen maken

De functie WERKDAG

U kunt een lijst maken met alleen de werkdagen, met de functie WERKDAG. Die geeft vanaf een datum de datum die een aantal dagen later ligt en slaat daarbij de weekenden over.

Syntaxis van WERKDAG
=WERKDAG(begindatum; aantal dagen later; eventueel vakantiedagen)
Vul een datum in tussen dubbele aanhalingsteken of verwijs naar een cel. Geef als tweede argument op hoeveel werkdagen Excel verder moet tellen. Eventueel geeft u vakantiedagen op, hiervoor moet u verwijzen naar cellen met datums.

Voor een lijst met datums zonder de weekenden typt u de eerste datum in A1 en geeft u A2
=WERKDAG(A1;1)
Kopieer deze formule omlaag en u krijgt een lijst met alleen de werkdagen; de weekenden worden overgeslagen.

U kunt ook een aantal dagen verder tellen. Bijvoorbeeld
=WERKDAG("1-4-2012";10)
brengt u meteen bij vrijdag 13 april 2012; deze telt tien dagen verder en slaat zaterdag en zondag over.

Vanaf een streefdatum terugrekenen
Hebt u een product dat op een bepaalde datum af moet zijn en weet u het aantal dagen dat u nodig hebt, dan beekent u als volgt wanneer u moet beginnen. Typ de einddatum bijvoorbeeld in D2. Wilt u de datum veertien dagen daarvóór weten, waarbij de weekenden worden overgeslagen, dan typt u in E2 de formule
=WERKDAG(D2;-14)
U telt dus een aantal werkdagen terug met een negatief getal.
Wordt het aantal dagen berekend in C2, dan maakt u dat aantal dagen negatief met
=WERKDAG(D2;-C2)

Weekenden en vrije dagen overslaan
De functie WERKDAG kan behalve de weekenden, ook feestdagen en andere vrije dagen overslaan. Plaats deze datums in een aantal cellen onder elkaar (typ ze over uit een agenda), bijvoorbeeld in B4 tot en met B20. Deze lijst hoeft niet chronologisch te zijn en lege cellen ertussen zijn geen probleem.

Uit deze lijst haalt de functie WERKDAG de vrije dagen, als we daarnaar verwijzen in de formule, met het derde argument.
Typ 1-4-2012 in D1 en in D2 de formule
=WERKDAG(D2;1;B$4:B$20)
Kopieer deze omlaag en u krijgt de datums op een rij zonder de weekenden en vrije dagen.
Als een feestdag in het weekend valt (eerste paasdag valt altijd op zondag), telt die dag niet dubbel en wordt deze slechts een keer overgeslagen.

U kunt aan de lijst met de feestdagen ook uw eigen vakantie toevoegen. Typ hiervoor de datums van alle werkdagen van uw vakantie apart onder elkaar, onder de feestdagen. Vergeet u niet de verwijzing in de formule naar deze langere lijst aan te passen.
Staan de vrije dagen in uw werkblad, dan kunt u met de functie WERKDAG meer werkdagen verder tellen en de vrije dagen overslaan. Met bijvoorbeeld
=WERKDAG(D2;5;B4:B20)
krijgt u de vijfde werkdag na het weekend en eventuele vrije dagen.

Uitgebreid lezen over rekenen met datums?

De functie WERKDAG.INTL

Wilt u niet alleen vanaf een datum verder tellen en daarbij de vakanties en vrije dagen overslaan, maar ook bepaalde vaste dagen van de week, dan gebruikt u de functie WERKDAG.INTL.
Deze functie is nieuw vanaf Excel 2010 en werkt dus niet in oudere versies.

Syntaxis van WERKDAG.INTL
=WERKDAG.INTL(begindatum; aantal dagen later; weekend; verwijzing naar lijst met vrije dagen)
Vul een datum in tussen dubbele aanhalingsteken of verwijs hiervoor naar een cel. Geef als tweede argument een getal op, voor het aantal werkdagen dat Excel verder moet tellen. Weekend en vrije dagen zijn optionele argumenten die u met een code opgeeft.
Resultaat: de datum, een aantal dagen later, waarbij de weekenden of vaste doordeweekse dagen en vrije dagen worden overgeslagen.

In het argument 'weekend', geeft u op welke dagen u wilt worden overslaan, dat kunnen ook doordeweekse dagen zijn. Hiervoor geeft u een code op: dat is een getal uit onderstaande tabel of een reeks nullen en enen.

Code = dagen die worden overgeslagen
1 of spatie = zaterdag en zondag
2 = zondag en maandag
3 = maandag en dinsdag
4 = dinsdag en woensdag
5 = woensdag en donderdag
6 = donderdag en vrijdag
7 = vrijdag en zaterdag
11 = alleen zondag
12 = alleen maandag
13 = alleen dinsdag
14 = alleen woensdag
15 = alleen donderdag
16 = alleen vrijdag
17 = alleen zaterdag

Enkele voorbeelden van de functie WERKDAG.INTL
We gaan uit van 1 april 2012. Typ deze datum in cel D2. De formule in zijn eenvoudigste vorm is
=WERKDAG.INTL(D2;1)
Kopieert u deze omlaag, dan krijgt u een lijst met werkdagen. Het argument 'weekend' is niet opgegeven, de berekening slaat standaard zaterdag en zondag over.

Met een waarde voor het argument 'weekend' geeft u aan, welke dagen u wilt overslaan. Wilt u bijvoorbeeld de werkdagen volgens de werkweek van moslims op een rij, dan geeft u als code 6 op, die donderdag en vrijdag overslaat. Typ 1-4-2012 in D2 en voer in D3 de formule in:
=WERKDAG.INTL(D2;1;6)
Kopieer deze omlaag en u hebt een lijst zonder donderdagen en vrijdagen.

Met de codes uit de tabel kunt u wel een of twee vaste vrije dagen opgeven, maar u kunt daarmee niet tegelijk de weekenden overslaan. Dat kan wel als u het derde argument 'weekend' instelt met een serie nullen en enen tussen dubbele aanhalingstekens. Die staan voor de zeven dagen van de week, te beginnen op maandag. Een 0 staat voor een dag die u wilt meetellen en elke 1 voor een dag die u wilt overslaan. Bijvoorbeeld
"0000011" = zaterdag en zondag overslaan
"1000100" = maandag en vrijdag overslaan

Bent u parttimer en werkt u alleen op maandag, woensdag en vrijdag, dan stelt u zo razendsnel een lijst samen met de dagen waarop u moet werken: uw arbeidspatroon. Naast uw vrije doordeweekse dagen wilt u ook de weekenden weglaten.
Typ de begindatum in cel A1 en typ daaronder de formule
=WERKDAG.INTL(A1;1;"0101011")
Deze telt vanaf de datum in A1 steeds één werkdag verder.
Kopieer deze formule omlaag en u krijgt een lijst met uw te werken dagen.