Uw projecten plannen met Excel

Met dit schema kunt u uw projecten plannen.
* vul in hoeveel werkdagen het project duurt
* geef de Startdatum op

Moet het volgende project aansluiten?
* kies dan het aantal dagen
* kies voor of na
* het begin of eind van het vorige project.

Het schema geeft met blauwe balken de planning weer, vrije dagen zijn oranje (die worden overgeslagen),
de laatste dag is rood (de deadline).
* Alleen de werkdagen worden gepland: weekends, feest- en vrije dagen worden automatisch overgeslagen.
* Bij o.a. Carnaval en Goede Vrijdag kunt u kiezen of dat werkbare dagen zijn.
* U kunt zelf niet-werkbare dagen en vakanties toevoegen.

Project Planning werkt in Excel 2007, 2010 en 2013.

Bestel het Excel-schema Project Planning voor 
slechts € 25,-.
Maak kans op een gratis exemplaar, want iedere vijfde besteller krijgt hem gratis!
Foto
Met dit schema in Excel hebt u geen MS Project meer nodig

Koningsdag berekenen

Vanaf 2014 wordt koningsdag gevierd op 27 april. Maar als dat op zondag valt, gaat het naar zaterdag 26 april.
U berekent koningsdag in Excel met de formule
=ALS(WEEKDAG(DATUM(C2;4;27))=1;DATUM(C2;4;26);DATUM(C2;4;27))
Hier staat het jaartal in cel C2
De formule houdt in: als de weekdag van 27 april een 1 is (d.w.z.: op zondag valt), neem dan 26 april; geef in de andere gevallen 27 april.
Het kan ook met een kortere formule:
=DATUM(C2;4;27)-ALS(WEEKDAG(DATUM(C2;4;27))=1;1;0)
Deze houdt in: neem de datum 27 april en als de weekdag van 27 april een zondag is, trek er dan 1 van af.

Koningsdag of koninginnedag?

In de jaren vóór 2014 is koninginnedag op 30 april. Ook daarbij geldt de regel: valt dat op zondag, dan wordt het een dag eerder. Als het jaartal in C2 staat, is uw formule 
=ALS(C2>2013;ALS(WEEKDAG(DATUM(C2;4;27))=1;DATUM(C2;4;26);DATUM(C2;4;27));ALS(WEEKDAG(DATUM(C2;4;30))=1;DATUM(C2;4;29);DATUM(C2;4;30)))
Die betekent: als het jaartal hoger is dan 2013, kijk dan of de weekdag van 27 april een 1 is (op zondag valt), en neem dan 26 april; geef anders 27 april; en als het jaartal niet hoger is dan 2013, kijk dan of de weekdag van 30 april een 1 is (op zondag valt), en neem dan 29 april; geef anders 30 april.
Deze kan ook compacter:
=ALS(WEEKDAG(DATUM(C2;4;ALS(C2>2013;27;30)))=1;DATUM(C2;4;ALS(C2>2013;26;29));DATUM(C2;4;ALS(C2>2013;27;30)))
Hier staat: als de weekdag van (na 2013 op 27 en anders op 30) april 1 is (op zondag valt), geef dan (na 2013 op 26 en anders 29) april; en geef anders de datum van (na 2013 op 27 en anders op 30) april.

Hoe Excel rekent met datums

Voor het rekenen met datums kent Excel aan één dag de waarde 1 toe. Het programma telt de dagen vanaf 1 januari 1900. Bijvoorbeeld 1 januari 2000 heeft het getal 36526, want het was toen 100 jaar en 25 schrikkeldagen later.
Dat u zo'n getal als een datum ziet, komt alleen door de opmaak. Deze opmaak als datum komt automatisch als u een datum invoert als 7-3-2012 of als 7/3/2012.
Tip 1: u voert de datum van vandaag in door te drukken op Ctrl+; (puntkomma) gevolgd door Enter.
Tip 2: valt de datum in het huidige jaar, dan hoeft u het jaartal er niet bij te typen, dat voegt Excel eraan toe. 
Typ 7-3 en u krijgt 7-3-2012 (kijk hiervoor in de formulebalk).

Aantal dagen tussen twee datums

Wilt u het verschil tussen twee datums weten, dan trekt u ze van elkaar af. Typ bijvoorbeeld in A1 de ene datum en in B2 de andere datum (B2 moet later vallen dan A2).
Zet ernaast de formule
=B2-A2
U ziet het aantal dagen dat ertussen ligt.

Feestdagen in een willekeurig jaar

Geef een jaar op en Excel laat de feestdagen zien. 
Download dit kant-en-klare werkblad met feestdagen.
Hier kan uw advertentie staan.
30.000 bezoekers per maand.

Zelf leren werken met Excel?

Ik kom graag op uw bedrijf een cursus Excel geven. Over datums en over talloze andere interessante rekenfuncties. In overleg spreken we af wat u gaat leren. Dit kan met beginners en gevorderden, en kan gaan over Excel 2003, 2007, 2010 of 2013.

Niet gevonden?

Dit is de meest bezochte pagina van deze website.
* Vindt u nog niet wat u zoekt?
Stuur uw vraag en u krijgt persoonlijk antwoord.

Formules voor datums

Functie in een voorbeeld:
=DAG("13-12-2012")
=MAAND("13-12-2012")
=JAAR("13-12-2012")
=("13-12-2012"-"1-1-2012")
=DAGEN360("1-1-2012";"13-12-2012")

=DATUMVERSCHIL("1-1-2012";"13-12-2012";"d")
=DATUMVERSCHIL("1-1-2011";"13-12-2012";"m")
=DATUMVERSCHIL("1-1-2010";"13-12-2012";"y")
=DATUMVERSCHIL("1-1-2010";"13-02-2012";"yd")

=DATUMVERSCHIL("1-1-2010";"13-05-2012";"ym")
Toelichting:
Geeft uit een datum de dag van de maand
Geeft uit een datum de maand
Geeft uit een datum het jaartal
Aantal dagen tussen twee datums
Aantal dagen tussen twee datums met jaar van 360 dagen
Aantal dagen tussen twee datums
Aantal hele maanden tussen twee datums
Aantal hele jaren tussen twee datums
Aantal dagen tussen beide datums, zonder de hele jaren
Aantal maanden tussen beide datums, zonder de hele jaren
Uitkomst:
13
12
2012
347
342

347
23
2
43

4
=DATUM(2012;3;7)
=DATUMWAARDE("7-3-2012")
=JAAR.DEEL("1-1-2012";"13-12-2012")

=LAATSTE.DAG("15-12-2012";3)

=NETTO.WERKDAGEN("1-1-2012";"13-12-2012") 

=WEEKDAG("13-12-2012")

=WEEKNUMMER("13-12-2012")


=WERKDAG("13-12-2012";7) 
=ZELFDE.DAG("13-12-2012";12)

=ZELFDE.DAG("13-12-2012";12,5*12)
Stelt datum samen uit: jaar, maand, dag
Geeft serieel getal van een datum
Geeft het deel van een jaar tussen twee datums, als een getal tussen 0 en 1
Telt x maanden verder en geeft de laatste dag van die maand
Geeft het aantal hele werkdagen tussen twee datums
Geeft uit een datum de dag van de week:
van 1=zondag tot en met 7=zaterdag
Geeft het weeknummer van een datum,
volgens Amerikaanse telling!
 * zie voor Europese telling hieronder
Geeft vanaf een datum x aantal werkdagen later
Geeft een datum, een x aantal maanden na de opgegeven datum
Bijv 12,5 jaar later geeft u op als 12,5 maal 12 maanden
07-03-2012
40975
0,95

31-03-2013

249

5

50


24-12-2010
13-12-2013

13-06-2025

Formules met VANDAAG

In deze voorbeelden is het vandaag 16 juli 2012
Functie in een voorbeeld:
=VANDAAG()
=ZELFDE.DAG(VANDAAG();1)
=LAATSTE.DAG(VANDAAG();0)
=LAATSTE.DAG(VANDAAG();1)
=GEHEEL((MAAND(VANDAAG())+2)/3)
=GEHEEL((MAAND(VANDAAG())+2)/3)+1

Toelichting:
Geeft de datum van vandaag
Vandaag over een maand
Einde van de huidige maand
Einde van de volgende maand
Huidige kwartaal
Volgende kwartaal

Uitkomst:
16-07-2012
16-08-2012
31-07-2011
31-08-2011
3
4

Leeftijd berekenen

U kunt met Excel iemands leeftijd berekenen als u de geboortedatum weet. Dat kan op twee manieren.
1. Hoe oud wordt diegene tijdens dit jaar?

U trekt hiervoor het geboortejaar af van het huidige jaar.
Staat de geboortedatum in F2, dan neemt u
=JAAR(VANDAAG())-JAAR(F2)

Hierbij maakt het niet uit, wanneer in het jaar de verjaardag valt.
2. Hoe oud is diegene vandaag?

U krijgt precies de leeftijd op dit moment, met
=DATUMVERSCHIL(F2;VANDAAG();"y")  

Deze formule houdt wel rekening met de verjaardag: zolang de persoon nog niet jarig is geweest, is deze een jaartje jonger, vanaf de verjaardag hebt u de actuele leeftijd. 
Dan is het resultaat weer hetzelfde als met JAAR.

Op welke datum valt deze verjaardag?

Welke dag van de week is die datum?
Iemand is geboren op 17-5-78 en u wilt weten op welke dag van de week de verjaardag dit jaar valt.
Typ, bijvoorbeeld in cel B2, de datum 17-5-1978.
Om 17-5 van dit jaar te krijgen, hebt u de volgende onderdelen nodig:
* JAAR(VANDAAG()) geeft het jaartal van vandaag;
overigens mag dit ook met JAAR(NU())
* MAAND(B2) geeft de maand van B2 en
* DAG(B2) geeft de dag van B2.

Met deze onderdelen geeft de functie DATUM de datum uit B2 in het huidige jaar; de formule is
=DATUM(JAAR(VANDAAG());MAAND(B2);DAG(B2))
Wilt u van een datum zien op welke dag van de week die valt, dan regelt u dat met de Opmaak.
Klik op de cel met de datum.
In Excel 2003:
Klik op Opmaak, Celeigenschappen. Klik op Aangepast (onder in het venster) en typ in het vak onder Type de code:
dddd d mmmm jjjj

In Excel 2007, 2010 en 2013:
Open in het tabblad Start het opmaakmenu boven in de groep Getal. Klik in dat menu op Lange datumnotatie.
De datum 16-7-1985 ziet er dan uit als:
dinsdag 16 juli 1985

Of gebruik de functie WEEKDAG. Met
=WEEKDAG(B2)
ziet u een cijfer 1 t/m 7, voor zondag t/m zaterdag.

Jubileum voorspellen

Typt u een datum in bijvoorbeeld cel A2, dan vindt u de datum 25 jaar later met de volgende formule:
=DATUM(JAAR(A2)+25;MAAND(A2);DAG(A2))
In Excel 2007, 2010 en 2013 kan dit ook met
=ZELFDE.DAG(A2;25*12)
Wilt u weten wanneer het 12,5 jaar na de datum in A2 is, dan neemt u
=DATUM(JAAR(A2);MAAND(A2)+12,5*12;DAG(A2))
In Excel 2007, 2010 en 2013 kan dit ook met
=ZELFDE.DAG(A2;12,5*12)

Datum van Pasen berekenen

De christelijke feesten in het voorjaar hangen samen met de datum van Pasen. Pasen valt op de eerste zondag na de eerste volle maan na het begin van de lente (21 maart).
Deze formule is correct tot het jaar 2078:

Deze formule klopt tot 2368:
Typ een jaartal in cel C3 (tussen 1900 en 9999).
Met de volgende formule berekent Excel de datum van Eerste Paasdag voor elk willekeurig jaar. Het jaartal staat in C3.


=VAST(("4/"&C3)/7+REST(REST(C3;19)*19-7;30)*14%;0)*7-6

=AFRONDEN.BENEDEN(DATUM(C3;5;DAG(MINUUT(C3/38)/2+56));7)-34
Plaats deze formule in cel C8.
De volgende feesten worden afgeleid van de Paasdatum en verwijzen daarom steeds naar C8.
U kunt onderstaande formules ook in een kant-en-klaar werkblad downloaden.

Feestdagen berekenen

Carnaval
Aswoensdag
Goede Vrijdag
Tweede Paasdag
Hemelvaartsdag
Eerste Pinksterdag
Tweede Pinksterdag

Kerst berekent u met de functie DATUM
Eerste Kerstdag
Tweede Kerstdag
=C8-49
=C8-46
=C8-2
=C8+1
=C8+39
=C8+49
=C8+50


=DATUM(C3;12;25)
=DATUM(C3;12;26)
in cel C5
in cel C6
in cel C7
in cel C9
in cel C10
in cel C11
in cel C12


in cel C13
in cel C14
Andere bijzondere datums
Begin van zomertijd - laatste zondag in maart 
Begin van wintertijd - laatste zondag in oktober
Moederdag - tweede zondag in mei
Vaderdag - derde zondag in juni
Prinsjesdag - derde dinsdag in september

Het Chinees Nieuwjaar berekent u met
Ook hier staat het jaartal in cel C3.
=DATUM(C3;3;31)-WEEKDAG(DATUM(C3;3;31))+1
=DATUM(C3;10;31)-WEEKDAG(DATUM(C3;10;31))+1
=DATUM(C3;5;14)-WEEKDAG(DATUM(C3;5;14))+1
=DATUM(C3;6;21)-WEEKDAG(DATUM(C3;6;21))+1
=DATUM(C3;9;19)-WEEKDAG(DATUM(C3;9;19))+3 

=GEHEEL(DATUM(C3-1;12;21)+61,6-REST(DATUM(C3-1;12;21);(19*354+11*355)/360))+ALS(EN(REST(REST(C3;29,53);19)>8,6;REST(REST(C3;29,53);19)<10,6);1;0)
Islamitische feesten:

Begin van de Ramadan
Suikerfeest - 30 dagen later
Offerfeest - 14 weken / 98 dagen later

Joodse feesten:
Rosj haSjana - Nieuwjaar



Rosj Hasjana valt nooit op een woensdag, vrijdag of zondag, dus moet de volgende aanvulling erbij:



Yom Kippoer - Grote verzoendag
Soekot - Loofhuttenfeest
Simchat Thora - Vreugde der Wet
Typ een jaartal in cel C3 (tussen 1900 en 9999) en zet in cel C25:
=GEHEEL((C3-1900)*(19*354+11*355)/360*12+1421,44)
=C25+30  (in cel C26)
=C25+98  (in cel C27)

Het jaartal staat weer in C3 en de volgende formule komt in cel B30:
=DATUM(C3;8;31)+6,05+1,554*REST(12*(REST(C3;19)+1);19)+0,25*REST(C3-1900;4)-0,003*(C3-1900)

Deze komt in cel C30:
=B30+ALS(OF(WEEKDAG(B30)=1;WEEKDAG(B30)=4;WEEKDAG(B30)=6;EN(WEEKDAG(B30)=2;REST(12*(REST(C32;19)+1);19)>11));1;ALS(EN(WEEKDAG(P71)=3;REST(12*(REST(A2;19)+1);19)<12);2;0))
=C30+9  (in cel C31)
=C30+14  (in cel C32
=C30+22  (in cel C33)

Europees weeknummer berekenen

Als u het weeknummer van een datum berekent met de functie WEEKNUMMER, klopt de uitkomst niet altijd. Dat komt doordat Excel voor deze functie het Amerikaanse systeem gebruikt. In de VS is de week met 1 januari altijd week 1 en begint week 2 op de zondag erna. Daardoor heeft week 1 meestal geen zeven dagen. Bijvoorbeeld in week 1 van 2010 zitten alleen 1 en 2 januari.
Maar de Europese telling werkt volgens ISO. In Europa geldt een weeknummer altijd voor zeven dagen. De week met de eerste donderdag van het jaar is week 1.
Daardoor krijgt u in sommige jaren een verschil.
U krijgt het weeknummer volgens de Europese telling met de formule:
=(A1-WEEKDAG(A1-1)+4-(GEHEEL(DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;2)/7)*7-2))/7
In dit voorbeeld staat de datum in cel A1.

Functie voor Europees weeknummer in Excel 2013

In Excel 2013 is dit gedoe voorbij. Hierin is de functie ISO.WEEKNUMMER geïntroduceerd.
Als de datum in A1 staat, is uw formule
=ISO.WEEKNUMMER(A1)
U krijgt het weeknummer van deze datum, volgens het ISO-systeem.
Deze functie is nieuw vanaf Excel 2013 en werkt dus niet in oudere versies.

Help! Ik zie geen datum, maar een groot getal

Zoals bovenaan uitgelegd, is een datum voor Excel een getal. Alleen door de opmaak ziet u dat als een datum.
* Ziet u onverwacht een groot getal rond de 40.000 en wilt u daar een datum zien, maak die cel dan op als Datum.
* Of misschien hebt u per ongeluk op de toetsen Ctrl+T gedrukt. Daardoor krijgt u namelijk alle formules in het werkblad te zien in plaats van hun uitkomsten. En datums veranderen dan in hun
getalswaarde. Druk nogmaals op Ctrl+T en u ziet de getallen weer als datums.
Omgekeerd: bent u benieuwd welke getalswaarde achter een datum in uw werkblad zit, klik dan in de tab Start op de keuzelijst Getalnotatie (in de groep Getal); er gaat een keuzelijst open. Kijk daarin bij Getal en u ziet de achterliggende getalswaarde van die datum.

Werkplanning: lijst met werkdagen maken

De functie WERKDAG

U kunt een lijst maken met alleen de werkdagen, met de functie WERKDAG. Die geeft vanaf een datum de datum die een aantal dagen later ligt en slaat daarbij de weekenden over.

Syntaxis van WERKDAG
=WERKDAG(begindatum; aantal dagen later; eventueel vakantiedagen)
Vul een datum in tussen dubbele aanhalingsteken of verwijs naar een cel. Geef als tweede argument op hoeveel werkdagen Excel verder moet tellen. Eventueel geeft u vakantiedagen op, hiervoor moet u verwijzen naar cellen met datums.

Voor een lijst met datums zonder de weekenden typt u de eerste datum in A1 en geeft u A2
=WERKDAG(A1;1)
Kopieer deze formule omlaag en u krijgt een lijst met alleen de werkdagen; de weekenden worden overgeslagen.

U kunt ook een aantal dagen verder tellen. Bijvoorbeeld
=WERKDAG("1-4-2012";10)
brengt u meteen bij vrijdag 13 april 2012; deze telt tien dagen verder en slaat zaterdag en zondag over.

Vanaf een streefdatum terugrekenen
Hebt u een product dat op een bepaalde datum af moet zijn en weet u het aantal dagen dat u nodig hebt, dan beekent u als volgt wanneer u moet beginnen. Typ de einddatum bijvoorbeeld in D2. Wilt u de datum veertien dagen daarvóór weten, waarbij de weekenden worden overgeslagen, dan typt u in E2 de formule
=WERKDAG(D2;-14)
U telt dus een aantal werkdagen terug met een negatief getal.
Wordt het aantal dagen berekend in C2, dan maakt u dat aantal dagen negatief met
=WERKDAG(D2;-C2)

Weekenden en vrije dagen overslaan
De functie WERKDAG kan behalve de weekenden, ook feestdagen en andere vrije dagen overslaan. Plaats deze datums in een aantal cellen onder elkaar (typ ze over uit een agenda), bijvoorbeeld in B4 tot en met B20. Deze lijst hoeft niet chronologisch te zijn en lege cellen ertussen zijn geen probleem.

Uit deze lijst haalt de functie WERKDAG de vrije dagen, als we daarnaar verwijzen in de formule, met het derde argument.
Typ 1-4-2012 in D1 en in D2 de formule
=WERKDAG(D2;1;B$4:B$20)
Kopieer deze omlaag en u krijgt de datums op een rij zonder de weekenden en vrije dagen.
Als een feestdag in het weekend valt (eerste paasdag valt altijd op zondag), telt die dag niet dubbel en wordt deze slechts een keer overgeslagen.

U kunt aan de lijst met de feestdagen ook uw eigen vakantie toevoegen. Typ hiervoor de datums van alle werkdagen van uw vakantie apart onder elkaar, onder de feestdagen. Vergeet u niet de verwijzing in de formule naar deze langere lijst aan te passen.
Staan de vrije dagen in uw werkblad, dan kunt u met de functie WERKDAG meer werkdagen verder tellen en de vrije dagen overslaan. Met bijvoorbeeld
=WERKDAG(D2;5;B4:B20)
krijgt u de vijfde werkdag na het weekend en eventuele vrije dagen.

Vlot leren rekenen met datums

Ik kom graag op uw bedrijf een cursus Excel geven. Ook over talloze andere interessante rekenfuncties. In overleg spreken we af wat u gaat leren. Dit kan met beginners en gevorderden, en kan gaan over Excel 2003, 2007, 2010 of 2013.

Meer lezen over rekenen met datums?

Foto
De functies:
* WERKDAG
* WERKDAG.INTL
* NETTO.WERKDAGEN en
* NETWERKDAGEN.INTL
leg ik uitgebreid uit in Hoofdstuk 4 van mijn boek Excel voor Professionals.

Ze worden met afbeeldingen verhelderd.





Klik op het boek om het in te kijken en te bestellen.
Daarin leest u bijvoorbeeld ook hoe u een projectplanning in een Gantt-grafiek weergeeft.

De functie WERKDAG.INTL

Wilt u niet alleen vanaf een datum verder tellen en daarbij de vakanties en vrije dagen overslaan, maar ook bepaalde vaste dagen van de week, dan gebruikt u de functie WERKDAG.INTL.
Deze functie is nieuw vanaf Excel 2010 en bestaat niet in Excel 2007.

Syntaxis van WERKDAG.INTL
=WERKDAG.INTL(begindatum; aantal dagen later; weekend; verwijzing naar lijst met vrije dagen)
Vul een datum in tussen dubbele aanhalingsteken of verwijs hiervoor naar een cel. Geef als tweede argument een getal op, voor het aantal werkdagen dat Excel verder moet tellen. Weekend en vrije dagen zijn optionele argumenten die u met een code opgeeft.
Resultaat: de datum, een aantal dagen later, waarbij de weekenden of vaste doordeweekse dagen en vrije dagen worden overgeslagen.

In het argument 'weekend', geeft u op welke dagen u wilt worden overslaan, dat kunnen ook doordeweekse dagen zijn. Hiervoor geeft u een code op: dat is een getal uit onderstaande tabel of een reeks nullen en enen.

Code  /  dagen die worden overgeslagen
  1 of spatie = zaterdag en zondag
  2 = zondag en maandag
  3 = maandag en dinsdag
  4 = dinsdag en woensdag
  5 = woensdag en donderdag
  6 = donderdag en vrijdag
  7 = vrijdag en zaterdag
11 = alleen zondag
12 = alleen maandag
13 = alleen dinsdag
14 = alleen woensdag
15 = alleen donderdag
16 = alleen vrijdag
17 = alleen zaterdag

Enkele voorbeelden van de functie WERKDAG.INTL
We gaan we uit van 1 april 2012. Typ deze datum in cel D2. De formule in zijn eenvoudigste vorm is
=WERKDAG.INTL(D2;1)
Kopieert u deze omlaag, dan krijgt u een lijst met werkdagen. Het argument 'weekend' is niet opgegeven, de berekening slaat standaard zaterdag en zondag over. Ook 'vrije dagen' zijn niet opgegeven, dus maandag Tweede Paasdag doet gewoon mee. Dus deze geeft hetzelfde resultaat als de formule
=WERKDAG(D2;1)

Met een waarde voor het argument 'weekend' geeft u aan, welke dagen u wilt overslaan. Wilt u bijvoorbeeld de werkdagen volgens de werkweek van moslims op een rij, dan geeft u als code 6 op, die donderdag en vrijdag overslaat. Typ 1-4-2012 in D2 en voer in D3 de formule in:
=WERKDAG.INTL(D2;1;6)
Kopieer deze omlaag en u hebt een lijst zonder donderdagen en vrijdagen.

Met de codes uit de tabel kunt u wel een of twee vaste vrije dagen opgeven, maar u kunt daarmee niet tegelijk de weekenden overslaan. Dat kan wel als u het derde argument 'weekend' instelt met een serie nullen en enen tussen dubbele aanhalingstekens. Die staan voor de zeven dagen van de week, te beginnen op maandag. Een 0 staat voor een dag die u wilt meetellen en elke 1 voor een dag die u wilt overslaan. Bijvoorbeeld
"0000011" = zaterdag en zondag overslaan
"1000100" = maandag en vrijdag overslaan
"0001100" = donderdag en vrijdag overslaan.
(De code "1111111" is ongeldig, want die zou alle dagen moeten overslaan).

Bent u parttimer en werkt u alleen op maandag, woensdag en vrijdag, dan stelt u zo razendsnel een lijst samen met de dagen waarop u moet werken: uw arbeidspatroon. Naast uw vrije doordeweekse dagen wilt u ook de weekenden weglaten.
Typ 1-1-2012 in cel A1 en typ daaronder de formule
=WERKDAG.INTL(A1;1;"0101011")
Deze telt vanaf de datum in A1 steeds één dag verder. De nullen op de positie van maandag, woensdag en vrijdag duiden aan dat u die dagen wel wilt zien.
Kopieer deze formule omlaag en u krijgt een lijst met uw te werken dagen.

Wilt u vervolgens ook vrije dagen overslaan, dan verwijst u naar de lijst met vrije dagen in bijvoorbeeld B4 tot en met B20. Uw formule is
=WERKDAG.INTL(A1;1;"0000111";B$4:B$20)
Deze geeft steeds de eerste vier dagen van de week, maar slaat de vrije dagen over die in de lijst in B4 tot en met B20 voorkomen.

De functie NETTO.WERKDAGEN

Dit is het spiegelbeeld van de functie WERKDAG. Met WERKDAG berekent u een datum die vanaf een datum een opgegeven aantal dagen later komt (of eerder), NETTO.WERKDAGEN berekent hoeveel werkdagen er tussen twee datums zitten en houdt daarbij rekening met de weekenden.

Syntaxis van NETTO.WERKDAGEN
=NETTO.WERKDAGEN(begindatum; einddatum; eventueel verwijzing naar lijst met vrije dagen)
Vul de beide datums in tussen dubbele aanhalingsteken of verwijs hiervoor naar twee cellen.

Enkele voorbeelden:
=NETTO.WERKDAGEN("1-1-2012";"31-1-2012")
geeft 22, het aantal werkdagen tussen die beide datums.

=NETTO.WERKDAGEN(A1;A100)
geeft het aantal werkdagen tussen de beide datums die in A1 en in A100 staan.

De functie NETTO.WERKDAGEN slaat standaard de weekenden over. Deze kan ook de vrije dagen overslaan als die ergens op het werkblad staan.

=NETTO.WERKDAGEN("1-4-2012";"30-4-2012";B4:B20)
Levert 19 werkdagen in april op: de dagen minus de weekenden, minus de vrije dagen in april uit de lijst B4 tot en met B20.

=NETTO.WERKDAGEN(A1:A100;B4:B20)
geeft het aantal werkdagen tussen de datums in A1 en A100, minus de weekenden en de vrije dagen uit de lijst.

De functie NETWERKDAGEN.INTL

De functie NETWERKDAGEN.INTL berekent het verschil tussen twee datums en slaat daarbij vaste doordeweekse dagen en vrije dagen over. Deze is nieuw vanaf Excel 2010 en werkt dus niet in Excel 2007.

Syntaxis van NETWERKDAGEN.INTL
=NETWERKDAGEN.INTL(begindatum; einddatum; eventueel weekend; eventueel verwijzing naar lijst met vrije dagen)
Vul twee datums in tussen dubbele aanhalingsteken of verwijs hiervoor naar twee cellen. Weekend en vrije dagen zijn optionele argumenten die u met een code opgeeft.

Voor vaste dagen die u wilt overslaan, gebruikt u een van de codes uit de tabel in de paragraaf De functie WERKDAG.INTL hierboven).

Enkele voorbeelden
Werkt u alle dagen van de week, behalve op woensdag, en wilt u weten hoeveel dagen u moet werken tussen 16 april en 26 april 2012, dan plaatst u deze datums in D3 en D4 en neemt u de formule
=NETWERKDAGEN.INTL(D3;D4;14)
De code 14 hierin geeft aan dat de woensdag moet worden overgeslagen. Het resultaat is 9: in die periode vallen 9 werkdagen.

Wilt u vaste doordeweekse dagen tellen en de weekenden overslaan, dan neemt u
=NETWERKDAGEN.INTL(D3;D4;"0000111")
Door de code 0000111 tellen vrijdagen, zaterdagen en zondagen niet mee, de uitslag is 8: in die periode vallen 8 werkdagen.

Wilt u ook de vrije dagen overslaan, dan geeft u het vierde argument op, die verwijst naar een lijst met vrije dagen, dus.
=NETWERKDAGEN.INTL(D3;D4;"0000111";B4:B20)
De code 0000111 slaat vrijdag, zaterdag en zondag over en het laatste argument slaat de vrije dagen over die in de lijst in B4 tot en met B20 staan.