Wanneer begint mijn AOW? Vraag het aan Excel

Als je je eigen AOW-datum wilt weten, krijg je vaak ingewikkelde tabellen voorgeschoteld. In dit gratis Excel-bestand, vul je gewoon je geboortedatum in (of die van een ander).
Je ziet dan meteen:
- jouw AOW-datum
- hoe oud je dan bent (in jaren en maanden)
- hoe lang je nog mag (in jaren en maanden)
​
* Downloaden maar
Foto
Vul je geboortedatum in en je ziet meteen jouw AOW-datum.
Zo werkt het
Een formule met VERT.ZOEKEN haalt uit een tabel hoeveel maanden na 65 jaar je nog door mag. Daarmee wordt de AOW-datum samengesteld. De functie DATUMVERSCHIL berekent hoe oud je dan bent, in jaren en maanden.
In het bestand zit een grafiek die het opschuiven van de AOW-datum in beeld brengt. En de kolom die bij jou hoort, wordt rood. Dat trucje alleen al is het bestuderen waard!
* Meer over rekenen met datums
* Meer over allerlei grafieken
Foto
De kolom die bij jouw datum hoort, wordt rood.

Vlot leren rekenen met datums

Ik kom graag een training Excel op jouw bedrijf geven. Ook over talloze andere interessante rekenfuncties. In overleg spreken we af wat jullie gaan leren. Dit kan met beginners en gevorderden, en kan gaan over Excel 2007, 2010, 2013, 2016, 2019, 2021, 2024 of 365.
Uitgebreid lezen over datums
Alle functies op deze pagina leg ik uitgebreid uit in hoofdstuk 6 van mijn boek Excel voor Professionals, 4e en 5e Editie.
En in mijn boek Datum en tijd in Excel.
In beide boeken staan ook de functies:
* WERKDAG
* WERKDAG.INTL
* NETTO.WERKDAGEN en
* NETWERKDAGEN.INTL
En je leest hoe je een projectplanning als een Gantt-grafiek weergeeft.
Alles wordt met afbeeldingen verhelderd.
​
Klik op het boek om het in te kijken en te bestellen.

Op welke dag valt Koningsdag?

Sinds 2014 wordt koningsdag gevierd op 27 april. Als dat op zondag valt, verschuift het naar zaterdag 26 april.
Je berekent Koningsdag in Excel met de formule
=ALS(WEEKDAG(DATUM(C2;4;27))=1;DATUM(C2;4;26);DATUM(C2;4;27))
Vul het jaartal in cel C2 in.
De formule houdt in: als de weekdag van 27 april een 1 is (d.w.z.: op zondag valt), neem dan 26 april; geef in de andere gevallen 27 april.

Het kan ook met een kortere formule:
=DATUM(C2;4;27)-ALS(WEEKDAG(DATUM(C2;4;27))=1;1;0)
Deze houdt in: neem de datum 27 april en als de weekdag van 27 april een zondag is, trek er dan 1 van af.

Koningsdag of koninginnedag?

In de jaren vóór 2014 viel koninginnedag op 30 april. Ook daarbij gold de regel: viel het op zondag, dan werd het een dag eerder gevierd. Als het jaartal in C2 staat, is je formule 
=ALS(C2>2013;DATUM(C2;4;27)-ALS(WEEKDAG(DATUM(C2;4;27))=1;1;0);DATUM(C2;4;30)-ALS(WEEKDAG(DATUM(C2;4;30))=1;1;0))
Die betekent: als het jaartal groter is dan 2013, neem dan 27 april minus als de weekdag van 27 april een 1 is (op zondag valt) één dag en anders nul dagen; en als het jaartal niet hoger is dan 2013, neem dan 29 april minus als de weekdag van 30 april een 1 is (op zondag valt) één dag en anders nul dagen.

In de kortere versie wordt de formule:
=DATUM(C2;4;ALS(C2>2013;27;30))-ALS(WEEKDAG(DATUM(C2;4;ALS(C2>2013;27;30)))=1;1;0)
Hier staat: geef de datum van april in dat jaar en als het jaartal groter dan 2013 is neem dan de dag 27 en anders 30, en als de weekdag van (na 2013 op 27 en anders op 30) april 1 is (dus op zondag valt) trek er dan één dag af en anders nul dagen.

Hoe Excel rekent met datums

Voor het rekenen met datums kent Excel aan één dag de waarde 1 toe en telt het programma de dagen vanaf 1 januari 1900.
Bijvoorbeeld 1 januari 2000 heeft volgnummer 36526.
Het was toen 100 jaar en 25 schrikkeldagen later.
Dat je dit getal als datum ziet, komt alleen door de opmaak. Een cel krijgt automatisch de datum-opmaak als je een datum invoert als 7-3-2025 of als 7/3/2025.

Tips om een datum in te voeren

​Tip 1: je voert de datum van vandaag in door te drukken op Ctrl+; (Ctrl met puntkomma) gevolgd door Enter.
Tip 2: valt de datum in het huidige jaar, dan hoef je het jaartal er niet bij te typen, dat voegt Excel eraan toe. Typ bijvoorbeeld 7-3 en je krijgt automatisch 7-3-2025 in  het betreffende jaar (kijk hiervoor in de formulebalk).

Aantal dagen tussen twee datums

Wil je het verschil tussen twee datums weten, dan trek je ze van elkaar af. Typ bijvoorbeeld in A1 de ene datum en in B2 de andere datum (B2 moet later vallen dan A2).
Zet ernaast de formule
=B2-A2
Je ziet het aantal dagen dat ertussen ligt.

Feestdagen in een willekeurig jaar

Geef een jaar op en Excel laat de feestdagen zien. 
Download dit kant-en-klare werkblad met feestdagen.

Formules voor datums

In de volgende voorbeelden wordt de datum steeds opgeven in de formule zelf, tussen dubbele aanhalingstekens.
Maar de datum kan ook in een cel staan, dan verwijs je in de formule naar die cel.
Functie in een voorbeeld:
=DAG("1-7-2025")
=DAG(B3)
=MAAND("1-7-2025")
=JAAR("1-7-2025")
=("1-7-2025"-"1-1-2025")
=DAGEN360("1-1-2025";"1-7-2025")

=DATUMVERSCHIL("1-1-2025";"1-7-2025";"d")
=DATUMVERSCHIL("1-1-2023";"1-7-2025";"m")
=DATUMVERSCHIL("1-1-2021";"1-7-2025";"y")
=DATUMVERSCHIL("1-1-2021";"1-2-2025";"yd")
=DATUMVERSCHIL("1-1-2021";"1-7-2025";"ym")
=DATUMVERSCHIL("1-1-2021";"14-7-2025";"md")
Toelichting:
Geef uit een datum de dag van de maand
Geef de dag van de datum in B3
Geef uit een datum de maand
Geef uit een datum het jaartal
Aantal dagen tussen twee datums
Aantal dagen tussen twee datums, waarbij een jaar op 360 dagen wordt gesteld
Aantal dagen tussen de datums
Aantal hele maanden tussen de datums
Aantal hele jaren tussen de datums
Aantal dagen, zonder de jaren
Aantal maanden, zonder de jaren
Aantal dagen, zonder de jaren en maanden
Uitkomst:
1
bijv. 2
7
2025
181
180

182
30
4
31
6
13
=DATUM(2025;3;7)
=DATUMWAARDE("7-3-2025")
=JAAR.DEEL("1-1-2025";"1-7-2025")

=LAATSTE.DAG("5-7-2025";3)

=LAATSTE.DAG(A2; -2)
​

=NETTO.WERKDAGEN("1-1-2025";"31-12-2025")

=WEEKDAG("1-8-2025")

=WEEKNUMMER("1-7-2025")


=WERKDAG("1-7-2025";7)
=ZELFDE.DAG("1-7-2025";12)

=ZELFDE.DAG("1-7-2025";12,5*12)
Stel datum samen uit: jaar, maand, dag
Geef serieel getal van een datum
Geef het deel van een jaar tussen de datums, als een getal tussen 0 en 1
Tel x maanden verder en geef de laatste dag van die maand
De laatste dag van de een-na-laatste maand vóór de eerste dag van het verlof. ​Voor referteperiode van WAZO uitkering (typ startdatum in A2)
Geef het aantal hele werkdagen tussen twee datums
Geef uit een datum de dag van de week:
van 1=zondag tot en met 7=zaterdag
Geef het weeknummer van een datum
* volgens Amerikaanse telling! 
Zie voor Europese telling hieronder
Geef vanaf een datum x aantal werkdagen later
Geef een datum, een x aantal maanden na de opgegeven datum
Bijv. 12,5 jaar later geeft u op als 12,5 maal 12 maanden
07-03-2025
45.723
0,5

31-10-2025



​
262

6

27


10-7-2025
1-7-2026

1-1-2038

Formules met VANDAAG

In deze voorbeelden is het 'vandaag' 9 mei 2026
Functie in een voorbeeld:
=VANDAAG()
=ZELFDE.DAG(VANDAAG();1)
=LAATSTE.DAG(VANDAAG();0)
=LAATSTE.DAG(VANDAAG();1)
=GEHEEL((MAAND(VANDAAG())+2)/3)
=REST(GEHEEL((MAAND(VANDAAG())+2)/3);4)+1
met REST komt na kwartaal 4 weer kwartaal 1

Toelichting:
Geef de datum van vandaag
Vandaag over een maand
Einde van de huidige maand
Einde van de volgende maand
Huidige kwartaal
Volgende kwartaal

Uitkomst:
9-05-2026
9-06-2026
31-05-2026
30-06-2026
2
3

Leeftijd berekenen

Je kunt met Excel iemands leeftijd berekenen als je de geboortedatum weet. Dat kan op twee manieren.
Hoe oud wordt iemand ergens in dit jaar?
Je trekt hiervoor het geboortejaar af van het huidige jaar.
Staat de geboortedatum in cel A2, dan neem je:
=JAAR(VANDAAG())-JAAR(A2)

Hierbij maakt het niet uit wanneer in het jaar de verjaardag valt. Je ziet hoe oud diegene aan het eind van het jaar is.
  
Hoe oud is iemand op een bepaalde dag?
Je wilt de leeftijd weten op een bepaalde peildatum, bijvoorbeeld: hoe oud is iemand op 15-9-2025?
Typ dan de datum 15-9-2025 eenmalig in bijvoorbeeld cel C1. Staat de eerste datum in A2, dan is je formule 
=GEHEEL((C$1-A2)/365,25)

Zie voor de toelichting hiernaast.
Staan er meer datums in kolom A, dan kun je de formule omlaag kopiëren. Doordat er een $ in C$1 staat, zullen alle kopieën verwijzen naar de cel met deze datum.
Wil je de leeftijd weten op een andere peildatum, dan hoef je alleen de datum in cel C1 maar te veranderen.

Je kunt ook gebruiken:
=DATUMVERSCHIL(A2;C$1;"y")
Hoe oud is iemand vandaag?
Hiervoor moet je het verschil hebben tussen vandaag en A2. Het ligt voor de hand om dat verschil in dagen te nemen en dat te delen door 365,25 (het aantal dagen per jaar plus gemiddeld één schrikkeldag per vier jaar). Als de geboortedatum in cel A2 staat, zou de formule zijn:
=(VANDAAG()-A2)/365,25

Maar de uitkomst klopt niet als het een schrikkeljaar is.
De functie die daar wel rekening mee houdt, is JAAR.DEEL. Die levert een getal met decimalen en daarvan hoeven we alleen het hele getal te zien. Dat krijg je met de formule:
=GEHEEL(JAAR.DEEL(VANDAAG();A2))

Ook hier staat de datum in cel A2. Het verschil in jaren wordt naar beneden afgerond.





​
​
Je kunt de leeftijd op dit moment ook berekenen met
=DATUMVERSCHIL(A2;VANDAAG();"y")

Haperende functie DATUMVERSCHIL

De functie DATUMVERSCHIL wordt verborgen gehouden. Je vindt er in de Hulp van Excel geen informatie over, in het tabblad Formules, in de keuzelijst Datum en tijd komt deze niet voor, je vindt deze functie niet via Functie invoegen en als je begint door =datum te typen, verschijnt deze ook niet in het menu. Je kunt een formule met DATUMVERSCHIL alleen invoeren door deze zelf voluit te typen.
Microsoft erkent dat de functie DATUMVERSCHIL niet goed werkt wanneer je als argument "m" of "md" gebruikt, die zijn voor het aantal hele maanden, dan wel dagen zonder hele jaren en maanden. ​
Geef je als datums bijvoorbeeld 31-3-2022 en 1-5-2022 op, dan wil je met "md" het verschil in dagen zien, zonder de hele maanden; je verwacht 1, maar je krijgt nul als resultaat.
Zolang je DATUMVERSCHIL gebruikt voor jaren en dagen, is er niets aan de hand. Maar wil je werken met maanden (met "m" of "md"), dan heb ik twee andere formules voor je. 

​In de volgende voorbeelden staat de oudste datum in A2 en de nieuwste in B2.

De fout in DATUMVERSCHIL corrigeren

Wil je het aantal hele maanden tussen deze twee datums zien, dan kun je DATUMVERSCHIL nemen, met de formule:
=DATUMVERSCHIL(A2;B2;"m")
Maar die geeft vaak een fout. Het gaat wel goed met de formule:
​​=REST(MAAND(B2)-MAAND(A2)+(JAAR(B2)-JAAR(A2)-1)*12;12)

​Deze neemt de maand van B2 en trekt daar de maand van A2 van af, neemt het verschil tussen hun beide jaartallen minus 1, maal 12 en telt dat daar bij op, en kijkt met REST hoeveel daarvan overblijft als je daar zo vaak mogelijk 12 van aftrekt.
​Je krijgt het aantal hele maanden tussen deze beide datums.

​​Wil je het aantal dagen zonder hele jaren en maanden zien, dan gaat dat niet altijd foutloos met:
=DATUMVERSCHIL(A2;B2;"md")
Neem in plaats daarvan:
​=REST(LAATSTE.DAG(A2;0)-A2+DAG(B2);DAG(LAATSTE.DAG(A2;0)))

​Deze berekent de laatste dag van de maand in A2, trekt daar de datum in A2 van af, je hebt dan de resterende dagen in die maand. Daar tel je de dag van B2 bij op en je hebt het aantal dagen verschil. En om de tussenliggende maanden er af te halen, gebruik je REST die de laatste dag van A2 zo vaak mogelijk aftrekt.
De uitkomst is het verschil in dagen met weglating van hele jaren en maanden.
Foto
Gebruik DATUMVERSCHIL niet met "m" of "md", maar neem deze formules.

Op welke datum valt deze verjaardag?

Welke dag van de week is die datum?
Iemand is geboren op 17-5-78 en je wilt weten op welke dag van de week de verjaardag dit jaar valt.
Typ, bijvoorbeeld in cel B2, deze datum 17-5-1978.
Om 17-5 van dit jaar te krijgen, heb je de volgende onderdelen nodig:
* JAAR(VANDAAG()) geeft het jaartal van vandaag;
dit mag ook met JAAR(NU())
* MAAND(B2) geeft de maand van B2
* DAG(B2) geeft de dag van B2.

Met deze onderdelen geeft de functie DATUM de datum uit B2 in het huidige jaar; de formule is
=DATUM(JAAR(VANDAAG());MAAND(B2);DAG(B2))
Wil je van een datum zien op welke dag van de week die valt, dan regel je dat met de Opmaak.
Klik met de rechtermuisknop op de cel met de datum; er gaat een menu open. Kies Celeigenschappen (of druk op Ctrl+1).
Klik op Aangepast (onder in het venster) en typ in het vak onder Type de code dddd d mmmm jjjj
Of open in het tabblad Start het opmaakmenu boven in de groep Getal en klik in dat menu op Lange datumnotatie.
De datum 16-7-1985 ziet er dan uit als:
dinsdag 16 juli 1985

Of gebruik de functie WEEKDAG. Met
=WEEKDAG(B2)
zie je een cijfer 1 t/m 7, voor zondag t/m zaterdag.

Jubileum voorspellen

Typ je een datum in bijvoorbeeld cel A2, dan vind je de datum 25 jaar later met de formule:
=DATUM(JAAR(A2)+25;MAAND(A2);DAG(A2))
In Excel 2007 en nieuwer kan dit ook met
=ZELFDE.DAG(A2;25*12)
Wil je weten wanneer het 12,5 jaar na de datum in A2 is, dan neem je:
=DATUM(JAAR(A2);MAAND(A2)+12,5*12;DAG(A2))
In Excel 2007 en nieuwer kan dit ook met:
=ZELFDE.DAG(A2;12,5*12)

Wanneer zijn wij samen 100 jaar?

Ook een mooie mijlpaal. Deze bereken je als volgt.
Typ de geboortedatum van de een in cel D2, en die van de ander in E2.
Typ in G2 de formule:
=GEMIDDELDE(D2:E2)
Je krijgt dan het gemiddelde van de beide geboortedata.
Typ in cel D5 het getal 100 (als je wilt weten wanneer je samen 100 jaar wordt).
Typ in cel E5 de formule
=G2+D5/2*365,25
Maak de cellen met datums op als Datum en je ziet wanneer je de mijlpaal bereikt.
Het kan ook korter
Je kunt de stap van de formule in cel G2 ook overslaan.
Typ wel de geboortedatums in cel D2 en in E2.
En typ in cel D5 het getal 100 (als je wilt weten wanneer je samen 100 jaar wordt).
Typ in cel E5 de formule:
=GEMIDDELDE(D2:E2)+D5/2*365,25

Als je wilt weten wanneer je samen 50 jaar wordt, hoef je alleen het getal in cel D5 aan te passen.
De formules hieronder staan ook in een bestand. Dat kun je gratis downloaden.

Datum van Pasen berekenen

De christelijke feesten in het voorjaar hangen samen met de datum van Pasen. Pasen valt op de eerste zondag na de eerste volle maan na het begin van de lente (21 maart).
Typ een jaartal in cel C2 (tussen 1900 en 9999).
Met de volgende formule berekent Excel de datum van Eerste Paasdag voor een willekeurig jaar (van 1901 tot en met 2368).
Het jaartal staat in C2.

=AFRONDEN.BENEDEN(DATUM(C2;5;DAG(MINUUT(C2/38)/2+56));7)-34
Plaats deze formule in cel C7.
* De volgende feesten worden afgeleid van de Paasdatum en verwijzen daarom steeds naar deze C7.

Feestdagen berekenen

Carnaval - 7 weken voor Pasen
Aswoensdag - 3 dagen later
Goede Vrijdag -  2 dagen voor Pasen
Tweede Paasdag - 1 dag na Pasen
Hemelvaartsdag - 40e dag na Pasen
Eerste Pinksterdag - 50e dag na Pasen
Tweede Pinksterdag - 1 dag later
=C7-49
=C7-46
=C7-2
=C7+1
=C7+39
=C7+49
=C7+50
in cel C4
in cel C5
in cel C6
in cel C7
in cel C9
in cel C10
in cel C11
* In de volgende voorbeelden staat het jaartal in cel C2.
Kerst bereken je met de functie DATUM
geef het jaartal op, dan de maand, dan de dag​
​Eerste Kerstdag - 25 dec
Tweede Kerstdag - 26 dec

​Andere bijzondere datums
Nieuwjaarsdag - 1 jan
​Valentijnsdag - 14 feb
Dag van de arbeid - 1 mei
Dodenherdenking- 4 mei
Bevrijdingsdag - 5 mei
Keti Koti (Suriname) - 1 juli
Nationale feestdag België - 21 juli
​Dierendag - 4 okt
​Allerheiligen - 1 nov
Sint Maarten - 11 nov
Wapenstilstand (België) - 11 nov
Onafhankelijkheid / Srefidensi (Suriname) - 25 nov
Sinterklaas - 5 dec
​Oudejaarsdag - 31 dec
​
​Begin van zomertijd - laatste zondag in maart 
Begin van wintertijd - laatste zondag in oktober
Moederdag - tweede zondag in mei
Vaderdag - derde zondag in juni
Prinsjesdag - derde dinsdag in september
Opbouw (synaxis) van de functie DATUM
​=DATUM(jaar; maand; dag)
=DATUM(C2;12;25)
=DATUM(C2;12;26)
​
​
​=DATUM(C2;1;1)
=DATUM(C2;2;14)
=DATUM(C2;5;1)
=DATUM(C2;5;4)
=DATUM(C2;5;5)
=DATUM(C2;7;1)
=DATUM(C2;7;21)
​=DATUM(C2;10;4)
=DATUM(C2;11;1)
​=DATUM(C2;11;11)​
=DATUM(C2;11;11)
=DATUM(C2;11;25)
=DATUM(C2;12;5)
=DATUM(C2;12;31)
​
​=DATUM(C2;3;31)-WEEKDAG(DATUM(C2;3;31))+1
=DATUM(C2;10;31)-WEEKDAG(DATUM(C2;10;31))+1
=DATUM(C2;5;14)-WEEKDAG(DATUM(C2;5;14))+1
=DATUM(C2;6;21)-WEEKDAG(DATUM(C2;6;21))+1
=DATUM(C2;9;19)-WEEKDAG(DATUM(C2;9;19))+3

Wanneer valt de Ramadan?

Islamitische feesten:

Begin van de Ramadan:
Suikerfeest - 30 dagen later:
Offerfeest - 14 weken / 98 dagen later:
Typ een jaartal in cel C2 (tussen 1900 en 9999) en zet in cel C25:
=GEHEEL((C2-1900)*19*354+11*355)/360*12+1421,44)
=C25+30  (in cel C26)
=C25+98  (in cel C27)

Wanneer vallen Pesach, Rosj Hasjana en Chanoeka?

Joodse feesten:
De meeste feesten hangen van Pesach af; deze berekenen we in drie stappen.
Deze zijn gebaseerd op de formules van C.F. Gauss. 
1. We beginnen met een formule die rekening houdt met het maanjaar en het zonnejaar. Deze geeft het aantal dagen na 13 maart:
​
2. Pesach valt nooit op maandag, woensdag of vrijdag, vandaar:

3. Daarmee wordt de datum van Pesach berekend:

Deze formule klopt van 1900 tot 2099,
daarna tel je er 1 (dag) bij op.


​​Typ een jaartal in cel C2
In het gratis bestand dat je kunt downloaden, staat de volgende formule in cel E33:
=20,0956+1,554*REST(12*C2+12;19)+REST(C2;4)/4-0,0031778*C2
​Deze staat ernaast, in cel F33:
=REST(3*C2+5*REST(C2;4)+GEHEEL(E31)+1;7)

Deze staat in C33:
DATUM(C2;3;13)+GEHEEL(E33)+ALS(OF(F33=2;F33=4;F33=6;EN(F33=0;REST(12*C2+12;19)>11;REST(E33;1)>=0,9));1;ALS(EN(F33=1;REST(12*C2+12;19)>6;REST(E33;1)>=0,6);2;0))
Poerim - Lotenfeest is 30 dagen voor Pesach:
​Sederavond - avond voor Pesach:
Sjawoeot - Wekenfeest is 50 dagen na Pesach
​Rosj Hasjana - Nieuwjaar is 163 dagen na Pesach:
Yom Kippoer - Grote verzoendag is 172 dagen na Pesach:
Soekot - Loofhuttenfeest is 177 dagen na Pesach:
Simchat Thora - Vreugde der Wet is 185 dagen na Pesach:
=C33-30
​=C33-1
​=C33+50
=C33+163
=C33+172
=C33+177
=C33+185
in cel C30
in cel C32
​in cel C36
in cel C38
in cel C40
in cel C41
in cel C43
​Chanoeka - Lichtjesfeest valt op 25 Kislev, maar de maand daarvóór (Chesjvan) is soms langer. 
​Hiervoor maken we een omweg.
1a. We berekenen eerst Pesach in het jaar erna. ​In cel E44 komt:
​=20,0956+1,554*REST(12*(C2+1)+12;19)+REST(C2+1;4)/4-0,0031778*(C2+1)

2a. Pesach valt nooit op maandag, woensdag of vrijdag. Zet daarvoor in cel F44:
=REST(3*(C2+1)+5*REST(C2+1;4)+GEHEEL(E44)+1;7)
​
3a. Daarmee wordt de datum van Pesach volgend jaar berekend. In G44 komt:​=DATUM(C2+1;3;13)+GEHEEL(E44)+ALS(OF(F44=2;F44=4;F44=6;EN(F44=0;REST(12*(C2+1)+12;19)>11;REST(E44;1)>=0,9));1;ALS(EN(F44=1;REST(12*(C2+1)+12;19)>6;REST(E44;1)>=0,6);2;0))
​​
4. En dan is het nog één stap voor de datum van Chanoeka. In C44 komt:
​=C38+ALS(OF(G44+163-C38=355;G44+163-C38=385);84;83)
​
5. Chanoeka duurt 8 dagen. Voor het einde van Chanoeka kun je eronder zetten, in C45:
=C44+8
Het Chinees Nieuwjaar bereken je, als het jaartal in C2 staat, met:
=GEHEEL(DATUM(C2-1;12;20)+61,66-REST(DATUM(C2-1;12;20);29,530556))
​+ALS(EN(REST(REST(C2;29,53);19)>8,6;REST(REST(C2;29,53);19)<10,6);1;0)

Formule voor Europees weeknummer

Als je het weeknummer van een datum berekent met de functie WEEKNUMMER, klopt de uitkomst niet altijd. Dat komt doordat Excel voor deze functie het Amerikaanse systeem gebruikt. In de VS is de week met 1 januari altijd week 1 en begint week 2 op de zondag erna. Daardoor heeft week 1 meestal geen zeven dagen. Bijvoorbeeld week 1 van 2026 bestaat alleen uit 1, 2 en 3 januari.
Maar de Europese telling werkt volgens ISO. In Europa geldt een weeknummer altijd voor zeven dagen. De week met de eerste donderdag van het jaar is week 1.
Daardoor krijg je in sommige jaren een verschil.

Functie voor Europees weeknummer vanaf Excel 2013

In Excel 2013 is de functie ISO.WEEKNUMMER geïntroduceerd en is dit gedoe voorbij.
Als de datum in cel A1 staat, is je formule
=ISO.WEEKNUMMER(A1)
Je krijgt het weeknummer van deze datum volgens het ISO-systeem.
* Heb je een oudere versie dan Excel 2013, dan krijg je het weeknummer volgens de Europese telling met:
=(A1-WEEKDAG(A1-1)+4-(GEHEEL(DATUM(JAAR(A1-WEEKDAG(A1-1)+4);1;2)/7)*7-2))/7

Help! Ik zie geen datum, maar een groot getal

Zoals bovenaan uitgelegd, verwerkt Excel een datum als een getal. Alleen door de opmaak zie je dat als een datum.
* Zie je onverwacht een groot getal rond de 40.000 en wil je daar een datum zien, maak die cel dan op als Datum.
* Misschien heb je per ongeluk op de toetsen Ctrl+T gedrukt. Daardoor zie je namelijk alle formules in het werkblad in plaats van hun uitkomsten. En datums veranderen dan in hun getalswaarde. Druk nogmaals op Ctrl+T en je ziet de getallen weer als datums.
Dit houdt dus ook in: wil je weten welke getalswaarde achter een datum in uw werkblad zit, klik dan in de tab Start op de keuzelijst Getalnotatie (in de groep Getal); er gaat een keuzelijst open. Daarin zie je bij Getal de achterliggende getalswaarde van die datum.

Werkplanning: lijst met werkdagen maken

De functie WERKDAG

Je kunt een lijst maken met alleen de werkdagen, met de functie WERKDAG. Die geeft vanaf een datum de datum die een aantal dagen later ligt en slaat daarbij de weekenden over.

Syntaxis van WERKDAG
=WERKDAG(begindatum; aantal dagen later; eventueel vakantiedagen)
Vul een datum in tussen dubbele aanhalingsteken of verwijs naar een cel. Geef als tweede argument op hoeveel werkdagen Excel verder moet tellen. Eventueel geef je vakantiedagen op, hiervoor moet je verwijzen naar cellen met datums.

Voor een lijst met datums zonder de weekenden typ je de eerste datum in A1 en geef je A2:
=WERKDAG(A1;1)
Kopieer deze formule omlaag en je krijgt een lijst met alleen de werkdagen; de weekenden worden overgeslagen.

Je kunt ook een aantal dagen verder tellen. Bijvoorbeeld:
=WERKDAG("1-4-2024";10)
brengt je meteen bij maandag 15 april 2024; deze telt tien dagen verder en slaat zaterdag en zondag over.

Vanaf een streefdatum terugrekenen
Moet een product op een bepaalde datum af zijn en weet je het aantal dagen dat je nodig hebt, dan bereken je als volgt wanneer je moet beginnen. Typ de einddatum bijvoorbeeld in D2. Wil je de datum veertien dagen daarvóór weten, waarbij de weekenden worden overgeslagen, dan typ je in E2 de formule:
=WERKDAG(D2;-14)
Met een negatief getal tel je dus een aantal werkdagen terug.
Wordt het aantal dagen berekend in C2, dan maak je dat aantal dagen negatief met:
=WERKDAG(D2;-C2)

Weekenden en vrije dagen overslaan
De functie WERKDAG kan behalve de weekenden, ook feestdagen en andere vrije dagen overslaan. Plaats deze datums in een aantal cellen onder elkaar (typ ze over uit een agenda), bijvoorbeeld in B4 tot en met B20. Deze lijst hoeft niet chronologisch te zijn en lege cellen ertussen zijn geen probleem.

Uit deze lijst haalt de functie WERKDAG de vrije dagen, als we daarnaar verwijzen in de formule, met het derde argument.
Typ 1-4-2024 in D1 en in D2 de formule:
=WERKDAG(D2;1;B$4:B$20)
Kopieer deze omlaag en je krijgt de datums op een rij zonder de weekenden en vrije dagen.
Als een feestdag in het weekend valt (eerste paasdag valt altijd op zondag), telt die dag niet dubbel en wordt deze slechts één keer overgeslagen.

Je kunt aan de lijst met de feestdagen ook je eigen vakantie toevoegen. Typ hiervoor de datums van alle werkdagen van je vakantie apart onder elkaar, onder de feestdagen. Vergeet niet de verwijzing in de formule naar deze langere lijst aan te passen.
Staan de vrije dagen in je werkblad, dan kun je met de functie WERKDAG meer werkdagen verder tellen en de vrije dagen overslaan. Met bijvoorbeeld:
=WERKDAG(D2;5;B4:B20)
krijg je de vijfde werkdag na het weekend en eventuele vrije dagen.

De functie WERKDAG.INTL

Wil je niet alleen vanaf een datum verder tellen en daarbij de vakanties en vrije dagen overslaan, maar ook bepaalde vaste dagen van de week, dan gebruik je de functie WERKDAG.INTL.
Deze functie is nieuw vanaf Excel 2010 en werkt dus niet in oudere versies.

Syntaxis van WERKDAG.INTL
=WERKDAG.INTL(begindatum; aantal dagen later; weekend; verwijzing naar lijst met vrije dagen)
Vul een datum in tussen dubbele aanhalingsteken of verwijs hiervoor naar een cel. Geef als tweede argument een getal op, voor het aantal werkdagen dat Excel verder moet tellen. Weekend en vrije dagen zijn optionele argumenten die je met een code opgeeft.
Resultaat: de datum, een aantal dagen later, waarbij de weekenden of vaste doordeweekse dagen en vrije dagen worden overgeslagen.

In het argument 'weekend', geef je op welke dagen je wilt overslaan, dat kunnen ook doordeweekse dagen zijn. Hiervoor geef je een code op: dat is een getal uit onderstaande tabel of een reeks nullen en enen.

Code = dagen die worden overgeslagen
  1 of spatie = zaterdag en zondag
  2 = zondag en maandag
  3 = maandag en dinsdag
  4 = dinsdag en woensdag
  5 = woensdag en donderdag
  6 = donderdag en vrijdag
  7 = vrijdag en zaterdag
11 = alleen zondag
12 = alleen maandag
13 = alleen dinsdag
14 = alleen woensdag
15 = alleen donderdag
16 = alleen vrijdag
17 = alleen zaterdag

Enkele voorbeelden van de functie WERKDAG.INTL
We gaan uit van 1 april 2024. Typ deze datum in cel D2. De formule daaronder in zijn eenvoudigste vorm is
=WERKDAG.INTL(D2;1)
Kopieer je deze omlaag, dan krijg je een lijst met werkdagen. Het argument 'weekend' is niet opgegeven, de berekening slaat standaard zaterdag en zondag over.

Met een waarde voor het argument 'weekend' geef je aan, welke dagen je wilt overslaan. Wil je bijvoorbeeld de werkdagen volgens de werkweek van moslims op een rij, dan geef je als code 6 op, die donderdag en vrijdag overslaat. Typ 1-4-2024 in D2 en voer in D3 de formule in:
=WERKDAG.INTL(D2;1;6)
Kopieer deze omlaag en je hebt een lijst zonder donderdagen en vrijdagen.

Met de codes uit de tabel kun je wel één of twee vaste vrije dagen opgeven, maar je kunt daarmee niet tegelijk de weekenden overslaan. Dat kan wel als je het derde argument 'weekend' instelt met een serie nullen en enen tussen dubbele aanhalingstekens. Die staan voor de zeven dagen van de week, te beginnen op maandag.
Een 0 staat voor een dag die je wilt meetellen en een 1 voor elke dag die je wilt overslaan. Bijvoorbeeld
"0000011" = zaterdag en zondag overslaan
"1000100" = maandag en vrijdag overslaan

Ben je parttimer en werk je alleen op maandag, woensdag en vrijdag, dan stel je zo snel een lijst samen met de dagen waarop je moet werken: je arbeidspatroon. Naast je vrije doordeweekse dagen wil je ook de weekenden weglaten.
Typ de begindatum in cel A1 en typ daaronder de formule:
=WERKDAG.INTL(A1;1;"0101011")
Deze telt vanaf de datum in A1 steeds één werkdag verder.
Kopieer deze formule omlaag en je krijgt een lijst met jouw te werken dagen.